Blitz3D Docs -> EntityPick

EntityPick ( entity,range# )

Parameters:

entity - entity handle
range# - range of pick area around entity

Description:

Returns the nearest entity 'ahead' of the specified entity. An entity must have a non-zero EntityPickMode to be pickable.

NB. the scale of the 'range' parameter is affected by the scale of the entity.

See also: EntityPick, LinePick, CameraPick, EntityPickMode.

Comments

Kryzon

(Posted 1+ years ago)

'ahead' - does it mean it's like a spherical pick around the specified entity? Would the "range#" value be the picking sphere's radius?

GIB3D

(Posted 1+ years ago)

Here's an example for EntityPick() that I put together.

InitGraphics(800,600)

Global Light = CreateLight()
	RotateEntity Light,20,0,0
	
Global Camera = CreateCamera()
	PositionEntity Camera,0,8,3
	RotateEntity Camera,90,-90,0
	CameraProjMode Camera,2
	CameraZoom Camera,.2
	
Global Range# = 3

Global Cube = CreateCube()
Global Cone = CreateCone(4,0,Cube)
	RotateEntity Cone,90,0,0
	PositionEntity Cone,0,0,1

Global RangePivot = CreatePivot(Cube)
	PositionEntity RangePivot,0,5,0
	ScaleEntity RangePivot,.05,.05,Range/2
	
Global RangeCone = CreateCylinder(16,1,RangePivot)
	EntityColor RangeCone,200,0,0
	PositionEntity RangeCone,0,0,1
	RotateEntity RangeCone,90,0,0
	EntityAlpha RangeCone,.5
	
Global Pickable = CreateSphere()
	PositionEntity Pickable,0,0,4
	EntityPickMode Pickable,2
	EntityColor Pickable,20,40,60
	
ShowAxis(EntityX(Pickable),EntityY(Pickable),EntityZ(Pickable))

While Not KeyDown(1)
	
	temprange# = Range
	
	If KeyDown(16) TurnEntity Cube,0,3,0
	If KeyDown(18) TurnEntity Cube,0,-3,0
	
	If KeyDown(200) MoveEntity Cube,0,0,.1
	If KeyDown(208) MoveEntity Cube,0,0,-.1
	If KeyDown(203) MoveEntity Cube,-.1,0,0
	If KeyDown(205) MoveEntity Cube,.1,0,0
	
	If KeyHit(12)
		Range=Range-.5
	EndIf
	
	If KeyHit(13)
		Range=Range+.5
	EndIf
	
	If temprange <> Range
		ScaleEntity RangePivot,.05,.05,Range/2
	EndIf
	
	EntityPick(Cube,Range)
	
	UpdateWorld
	RenderWorld
	
	If PickedEntity() <> 0
		CameraProject Camera,EntityX(Pickable,1),EntityY(Pickable,1),EntityZ(Pickable,1)
		
		Color 0,0,0
		Text ProjectedX()+1,ProjectedY()+1-40,"EntityPicked",1,1
		Text ProjectedX(),ProjectedY()+1-40,"EntityPicked",1,1
		
		Color 255,255,0
		Text ProjectedX(),ProjectedY()-40,"EntityPicked",1,1
	EndIf
	
	Color 255,0,0
	Text 300,500,"X"
	
	Color 0,0,255
	Text 100,320,"Z"
	
	Color 255,255,255
	Text 0,0,"<<< Forward <<<"
	
	Text 0,20,"Arrow keys to move : Q and E to turn : - and + to change the range"
	Text 0,40,"Range = " + Range
	
	Flip
	
Wend
End

Function InitGraphics(w = 1024, h = 768,title$="Blitz3D Program",exit_message$="")
	Graphics3D w, h, 32, 2
	SetBuffer BackBuffer()
	SeedRnd MilliSecs()
	
	If exit_message <> ""
		AppTitle title,exit_message
			Else
				AppTitle title
	EndIf
End Function

Function ShowAxis(x#,y#,z#)
	Local A[2]
	
	For xyz = 0 To 2
		A[xyz] = CreateCube()
		ScaleEntity A[xyz],.1,.1,3
		PositionEntity A[xyz],x,y,z
	Next
	
	EntityColor A[0],255,0,0
	EntityColor A[1],0,255,0
	EntityColor A[2],0,0,255
	
	RotateEntity A[0],0,90,0
	RotateEntity A[1],90,0,0
	
End Function

Kryzon

(Posted 1+ years ago)

Very good GIA. So in the end, it really is like a LinePick on the positive Z-Axis (if it were a spherical pick it would be much more useful...)

EdzUp[Using Unity]

(Posted 1+ years ago)

For a spherical pick use EntityDistance to see if an entity is within another entities distance.

_PJ_	(Posted 1+ years ago)

The fact that when the range is negative, then (logivcally) the pick is reversed so it checks BEHIND the source entity might also be useful -

Maybe some means of checking when a homing missile is locked on and about to hit or something.

Blitz3D Manual Forum

BlitzPlus Equivalent Command